------------------------------------------------
--Combinatorial commutative algebra class
------------------------------------------------
------------------------------------------------
--First example
------------------------------------------------
--If you take a 3 by 3 magic square, and read the
--rows as 3 digit number, then the sum of their 
--squares is the same as the sum of the squares of
--the rows read backwards.
------------------------------------------------
--Let the magic square be
--a b c
--d e f
--g h i
------------------------------------------------
R=QQ[a..i];
I=ideal(a+b+c-d-e-f, a+b+c-g-h-i, a+b+c-a-d-g, a+b+c-b-e-f,
a+b+c-c-f-i, a+b+c-a-e-i, a+b+c-c-e-g);
sums=(100*a+10*b+c)^2+(100*d+10*e+f)^2+(100*g+10*h+i)^2 -
(100*c+10*b+a)^2-(100*f+10*e+d)^2-(100*i+10*h+g)^2;
<<sums % I<<endl;

------------------------------------------------

[Diane-Maclagans-Computer:~/Current/class] maclagan% M2
Macaulay 2, version 
--Copyright 1993-2001, D. R. Grayson and M. E. Stillman
--Singular-Factory 1.3b, copyright 1993-2001, G.-M. Greuel, et al.
--Singular-Libfac 0.3.2, copyright 1996-2001, M. Messollen

i1 : R=QQ[a..i]

o1 = R

o1 : PolynomialRing
i2 : I=ideal(a+b+c-d-e-f, a+b+c-g-h-i, a+b+c-a-d-g, a+b+c-b-e-f,
a+b+c-c-f-i, a+b+c-a-e-i, a+b+c-c-e-g)     

o2 = ideal (a + b + c - d - e - f, a + b + c - g - h - i, b + c - d -
g, a + c - e - f, a + b - f - i, b + c - e - i, a + b - e - g)

o2 : Ideal of R

i3 :      sums=(100*a+10*b+c)^2+(100*d+10*e+f)^2+(100*g+10*h+i)^2 -
(100*c+10*b+a)^2-(100*f+10*e+d)^2-(100*i+1     0*h+g)^2

          2                            2        2                            2        2                            2
o3 = 9999a  + 1980a*b - 1980b*c - 9999c  + 9999d  + 1980d*e - 1980e*f - 9999f  + 9999g  + 1980g*h - 1980h*i - 9999i

o3 : R

i4 : toString sums

o4 =9999*a^2+1980*a*b-1980*b*c-9999*c^2+9999*d^2+1980*d*e-1980*e*f-9999*f^2+
9999*g^2+1980*g*h-1980*h*i-9999*i^2

i5 : <<sums % I<<endl
0

------------------------------------------------
------------------------------------------------
--Combinatorial commutative algebra class
------------------------------------------------
------------------------------------------------
--Second example
------------------------------------------------
--How many knights can be placed on a 5x5 chess board
--with no two attacking each other?
------------------------------------------------
n=5;
--R_k is the (i,j)th entry, when k=5i+j
R=QQ[x_1..x_(n^2)];
I=ideal(0_R);
--Now set up the equations
scan(n^2,k->(
	i=floor(k/n)+1;
	j=k+1-(i-1)*n;
	if i+1<n+1 then (
		if j+2<n+1 then I=I+ideal(R_k*R_(k+7));
		if j-2>0 then I=I+ideal(R_k*R_(k+3));
	);
	if i+2<n+1 then (
		if j+1<n+1 then I=I+ideal(R_k*R_(k+11));
		if j-1>0 then I=I+ideal(R_k*R_(k+9));
	);
));
<<"The ideal for these equations is: "<<toString I<<endl<<endl;
--Work out the number of knights
mm=dim(R/I);
<<"There can be "<<mm<<" knights"<<endl;
--Find an example of such a configuration
J=I;
scan(n^2,k->(J=J+ideal(R_k^2);));
bas=flatten entries basis(mm,R/J);
<<"An example of such a configuration is" <<toString bas<<endl;
------------------------------------------------
------------------------------------------------

[Diane-Maclagans-Computer:~/Current/class] maclagan% M2
Macaulay 2, version 
--Copyright 1993-2001, D. R. Grayson and M. E. Stillman
--Singular-Factory 1.3b, copyright 1993-2001, G.-M. Greuel, et al.
--Singular-Libfac 0.3.2, copyright 1996-2001, M. Messollen

i1 : load "555firstclassEG2.m2" 
The ideal for these equations is:
ideal(0,x_1*x_8,x_1*x_12,x_2*x_9,x_2*x_13,x_2*x_11,x_3*x_10,x_3*x_6,x_3*x_14,
x_3*x_12,x_4*x_7,x_4*x_15,x_4*x_13,x_5*x_8,x_5*x_14,x_6*x_13,x_6*x_17,x_7*x_14,
x_7*x_18,x_7*x_16,x_8*x_15,x_8*x_11,x_8*x_19,x_8*x_17,x_9*x_12,x_9*x_20,
x_9*x_18,x_10*x_13,x_10*x_19,x_11*x_18,x_11*x_22,x_12*x_19,x_12*x_23,x_12*x_21,
x_13*x_20,x_13*x_16,x_13*x_24,x_13*x_22,x_14*x_17,x_14*x_25,x_14*x_23,x_15*x_18,
x_15*x_24,x_16*x_23,x_17*x_24,x_18*x_25,x_18*x_21,x_19*x_22,x_20*x_23)

There can be 13 knights
An example of such a configuration is
{x_1*x_3*x_5*x_7*x_9*x_11*x_13*x_15*x_17*x_19*x_21*x_23*x_25}
--loaded 555firstclassEG2.m2

i2 :